media-radio/chirp/chirp-20250808.ebuild

   1 # Copyright 1999-2025 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 PYTHON_COMPAT=( python3_{10..13} )
   7 DISTUTILS_SINGLE_IMPL=1
   8 DISTUTILS_USE_PEP517=setuptools
   9
  10 inherit distutils-r1
  11
  12 DESCRIPTION="A free, open-source tool for programming your radio"
  13 HOMEPAGE="https://chirpmyradio.com/"
  14 SRC_URI="https://archive.chirpmyradio.com/${PN}_next/next-${PV}/${P}.tar.gz"
  15
  16 LICENSE="GPL-3+"
  17 SLOT="0"
  18 KEYWORDS="amd64 ~x86"
  19 IUSE="+gui"
  20
  21 RDEPEND="$(python_gen_cond_dep '
  22         dev-python/pyserial[${PYTHON_USEDEP}]
  23         dev-python/requests[${PYTHON_USEDEP}]
  24         dev-python/six[${PYTHON_USEDEP}]
  25         dev-python/lark[${PYTHON_USEDEP}]
  26         gui? (
  27                 dev-python/suds-community[${PYTHON_USEDEP}]
  28                 dev-python/wxpython:4.0[${PYTHON_USEDEP}]
  29                 dev-python/yattag[${PYTHON_USEDEP}]
  30         )
  31 ')"
  32 BDEPEND="test? ( $(python_gen_cond_dep '
  33         dev-python/ddt[${PYTHON_USEDEP}]
  34         dev-python/pytest-xdist[${PYTHON_USEDEP}]
  35         dev-python/pyyaml[${PYTHON_USEDEP}]
  36 ') )"
  37
  38 distutils_enable_tests pytest
  39
  40 # The alias map is an internal developer file not included in release tarballs.
  41 # Other disabled tests require Internet access.
  42 EPYTEST_DESELECT=(
  43         tests/unit/test_directory.py::TestAliasMap
  44         tests/unit/test_network_sources.py
  45         tests/unit/test_repeaterbook.py
  46 )
  47
  48 python_test() {
  49         # From the contents of tests/ upstream currently only runs unit and driver
  50         # tests, and the latter can take so long that they have even got a special
  51         # script for only running them on drivers whose code has changed
  52         # with respect to origin/master.
  53         epytest tests/unit/
  54 }
  55
  56 src_install() {
  57         distutils-r1_src_install
  58         if ! use gui; then
  59                 rm "${ED}"/usr/bin/${PN} || die
  60         fi
  61 }