From: Arthur Taft <arthur.taft2006@icloud.com>
Date: Tue, 12 Aug 2025 04:14:33 +0000 (-0600)
Subject: chirp version bump, add support for python 3.13
X-Git-Url: https://gitweb.arthurtaft.net/custom-tools.git/commitdiff_plain/285fb1f91ad85c423def8d334617742ec9071412

chirp version bump, add support for python 3.13
---

diff --git a/media-radio/chirp/Manifest b/media-radio/chirp/Manifest
new file mode 100644
index 0000000..5418285
--- /dev/null
+++ b/media-radio/chirp/Manifest
@@ -0,0 +1 @@
+DIST chirp-20250808.tar.gz 2415073 BLAKE2B 0f1846792d01643802454c175cdd97598f6d5f98277b55c001a1ca049bec64bafcae4081712fb255afcb0b60529fcb176aed1f3cd3ef20a6ce81fb5b06d549e5 SHA512 7daa89335d66f0ceefce934a3f39c68689f2fef42e8efa32e165354970d8eba140ffc8aca05d29353f2973d4f643c5a8d0af4388d83d217b2f800c9b3af373b3
diff --git a/media-radio/chirp/chirp-20250808.ebuild b/media-radio/chirp/chirp-20250808.ebuild
new file mode 100644
index 0000000..520c1f6
--- /dev/null
+++ b/media-radio/chirp/chirp-20250808.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+DESCRIPTION="A free, open-source tool for programming your radio"
+HOMEPAGE="https://chirpmyradio.com/"
+SRC_URI="https://archive.chirpmyradio.com/${PN}_next/next-${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="amd64 ~x86"
+IUSE="+gui"
+
+RDEPEND="$(python_gen_cond_dep '
+	dev-python/pyserial[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	gui? (
+		dev-python/suds-community[${PYTHON_USEDEP}]
+		dev-python/wxpython:4.0[${PYTHON_USEDEP}]
+		dev-python/yattag[${PYTHON_USEDEP}]
+	)
+')"
+BDEPEND="test? ( $(python_gen_cond_dep '
+	dev-python/ddt[${PYTHON_USEDEP}]
+	dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+') )"
+
+distutils_enable_tests pytest
+
+# The alias map is an internal developer file not included in release tarballs.
+# Other disabled tests require Internet access.
+EPYTEST_DESELECT=(
+	tests/unit/test_directory.py::TestAliasMap
+	tests/unit/test_network_sources.py
+	tests/unit/test_repeaterbook.py
+)
+
+python_test() {
+	# From the contents of tests/ upstream currently only runs unit and driver
+	# tests, and the latter can take so long that they have even got a special
+	# script for only running them on drivers whose code has changed
+	# with respect to origin/master.
+	epytest tests/unit/
+}
+
+src_install() {
+	distutils-r1_src_install
+	if ! use gui; then
+		rm "${ED}"/usr/bin/${PN} || die
+	fi
+}