media-radio/chirp/chirp-20250808.ebuild

   1 # Copyright 1999-2025 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 PYTHON_COMPAT=( python3_{10..13} )
   7 DISTUTILS_SINGLE_IMPL=1
   8 DISTUTILS_USE_PEP517=setuptools
   9
  10 inherit distutils-r1
  11
  12 DESCRIPTION="A free, open-source tool for programming your radio"
  13 HOMEPAGE="https://chirpmyradio.com/"
  14 SRC_URI="https://archive.chirpmyradio.com/${PN}_next/next-${PV}/${P}.tar.gz"
  15
  16 LICENSE="GPL-3+"
  17 SLOT="0"
  18 KEYWORDS="amd64 ~x86"
  19 IUSE="+gui"
  20
  21 RDEPEND="$(python_gen_cond_dep '
  22         dev-python/pyserial[${PYTHON_USEDEP}]
  23         dev-python/requests[${PYTHON_USEDEP}]
  24         dev-python/six[${PYTHON_USEDEP}]
  25         gui? (
  26                 dev-python/suds-community[${PYTHON_USEDEP}]
  27                 dev-python/wxpython:4.0[${PYTHON_USEDEP}]
  28                 dev-python/yattag[${PYTHON_USEDEP}]
  29         )
  30 ')"
  31 BDEPEND="test? ( $(python_gen_cond_dep '
  32         dev-python/ddt[${PYTHON_USEDEP}]
  33         dev-python/pytest-xdist[${PYTHON_USEDEP}]
  34         dev-python/pyyaml[${PYTHON_USEDEP}]
  35 ') )"
  36
  37 distutils_enable_tests pytest
  38
  39 # The alias map is an internal developer file not included in release tarballs.
  40 # Other disabled tests require Internet access.
  41 EPYTEST_DESELECT=(
  42         tests/unit/test_directory.py::TestAliasMap
  43         tests/unit/test_network_sources.py
  44         tests/unit/test_repeaterbook.py
  45 )
  46
  47 python_test() {
  48         # From the contents of tests/ upstream currently only runs unit and driver
  49         # tests, and the latter can take so long that they have even got a special
  50         # script for only running them on drivers whose code has changed
  51         # with respect to origin/master.
  52         epytest tests/unit/
  53 }
  54
  55 src_install() {
  56         distutils-r1_src_install
  57         if ! use gui; then
  58                 rm "${ED}"/usr/bin/${PN} || die
  59         fi
  60 }